Rules for integrands of the form  (((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)

1:  ∫(((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  q∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Rule: If  q∈(SuperPlus[ℤ]), let u->∫(((d+e (x^r)))^q)dx, then

∫(((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^r)^q,x]},
  u*(a+b*Log[c*x^n]) - b*n*Int[SimplifyIntegrand[u/x,x],x]] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[q,0]

Int[(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^r)^q,x]},
  Dist[(a+b*Log[c*x^n]),u] - b*n*Int[SimplifyIntegrand[u/x,x],x]] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[q,0]

2:  ∫(((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  r(q+1)+1==0

Derivation: Integration by parts

Basis: If  r(q+1)+1==0, then (((d+e (x^r)))^q)==(∂_x)((x (((d+e (x^r)))^(q+1)))/d)

Rule: If  r(q+1)+1==0, then

∫(((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  ((x (((d+e (x^r)))^(q+1)) (a+b Log[c (x^n)]))/d)-((b n)/d)∫(((d+e (x^r)))^(q+1))dx

Program code:

Int[(d_+e_.*x_^r_.)^q_*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  x*(d+e*x^r)^(q+1)*(a+b*Log[c*x^n])/d - b*n/d*Int[(d+e*x^r)^(q+1),x] /;
FreeQ[{a,b,c,d,e,n,q,r},x] && EqQ[r*(q+1)+1,0]

x:  ∫((((a+b Log[c (x^n)]))^p)/(d+e (x^r)))dx  when  p∈(SuperPlus[ℤ])∧ r∈(SuperPlus[ℤ])

Derivation: Algebraic expansion

Basis: ((x^m)/(d+e (x^r)))==((x^(m-r))/e)-((d (x^(m-r)))/(e (d+e (x^r))))

Note: This rule produces antiderivatives in terms of PolyLog[k,-(d/(e (x^r)))]

Rule: If  p∈(SuperPlus[ℤ])∧ r∈(SuperPlus[ℤ]), then

∫((((a+b Log[c (x^n)]))^p)/(d+e (x^r)))dx  ⟶  (1/e) ∫((((a+b Log[c (x^n)]))^p)/(x^r))dx-(d/e) ∫((((a+b Log[c (x^n)]))^p)/((x^r) (d+e (x^r))))dx

Program code:

(* Int[(a_.+b_.*Log[c_.*x_^n_.])^p_./(d_+e_.*x_^r_.),x_Symbol] :=
  1/e*Int[(a+b*Log[c*x^n])^p/x^r,x] - 
  d/e*Int[(a+b*Log[c*x^n])^p/(x^r*(d+e*x^r)),x] /;
FreeQ[{a,b,c,d,e,n,r},x] && IGtQ[p,0] && IGtQ[r,0] *)

3.  ∫(((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx

1.  ∫(((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  when  p>0

1.  ∫((((a+b Log[c (x^n)]))^p)/(d+e x))dx  when  p∈(SuperPlus[ℤ])

1.  ∫((a+b Log[c  x])/(d+e x))dx  when  -((c d)/e)>0

1:  ∫((Log[c x])/(d+e x))dx  when  e+c d==0

Rule: If  e+c d==0, then

∫((Log[c x])/(d+e x))dx  ⟶  -(1/e)PolyLog[2,1-c x]

Program code:

Int[Log[c_.*x_]/(d_+e_.*x_),x_Symbol] :=
  -1/e*PolyLog[2,1-c*x] /;
FreeQ[{c,d,e},x] && EqQ[e+c*d,0]

2:  ∫((a+b Log[c  x])/(d+e x))dx  when  -((c d)/e)>0

Derivation: Algebraic expansion

Basis: If -((c d)/e)>0, then Log[c x]==Log[-((c d)/e)]+Log[-((e x)/d)]

Note: Resulting integrand is of the form required by the above rule.

Rule: If -((c d)/e)>0, then

∫((a+b Log[c  x])/(d+e x))dx  ⟶  (((a+b Log[-((c d)/e)]) Log[d+e x])/e)+b∫((Log[-((e x)/d)])/(d+e x))dx

Program code:

Int[(a_.+b_.*Log[c_.*x_])/(d_+e_.*x_),x_Symbol] :=
  (a+b*Log[-c*d/e])*Log[d+e*x]/e + b*Int[Log[-e*x/d]/(d+e*x),x] /;
FreeQ[{a,b,c,d,e},x] && GtQ[-c*d/e,0]

2:  ∫((((a+b Log[c (x^n)]))^p)/(d+e x))dx  when  p∈(SuperPlus[ℤ])

Derivation: Integration by parts

Basis: (1/(d+e x))==(1/e) (∂_x)Log[1+((e x)/d)]

Basis: (∂_x)(((a+b Log[c (x^n)]))^p)==((b n p (((a+b Log[c (x^n)]))^(p-1)))/x)

Rule: If  p∈(SuperPlus[ℤ]), then

∫((((a+b Log[c (x^n)]))^p)/(d+e x))dx  ⟶  ((Log[1+((e x)/d)] (((a+b Log[c (x^n)]))^p))/e)-((b n p)/e)∫((Log[1+((e x)/d)] (((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_./(d_+e_.*x_),x_Symbol] :=
  Log[1+e*x/d]*(a+b*Log[c*x^n])^p/e - b*n*p/e*Int[Log[1+e*x/d]*(a+b*Log[c*x^n])^(p-1)/x,x] /;
FreeQ[{a,b,c,d,e,n},x] && IGtQ[p,0]

2:  ∫((((a+b Log[c (x^n)]))^p)/(((d+e x))^2))dx  when  p>0

Derivation: Integration by parts

Basis: (1/(((d+e x))^2))==(∂_x)(x/(d (d+e x)))

Basis: (∂_x)(((a+b Log[c (x^n)]))^p)==((b n p (((a+b Log[c (x^n)]))^(p-1)))/x)

Rule: If  p>0, then

∫((((a+b Log[c (x^n)]))^p)/(((d+e x))^2))dx  ⟶  ((x (((a+b Log[c (x^n)]))^p))/(d(d+e x)))-((b n p)/d)∫((((a+b Log[c (x^n)]))^(p-1))/(d+e x))dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])^p_./(d_+e_.*x_)^2,x_Symbol] :=
  x*(a+b*Log[c*x^n])^p/(d*(d+e*x)) - b*n*p/d*Int[(a+b*Log[c*x^n])^(p-1)/(d+e*x),x] /;
FreeQ[{a,b,c,d,e,n,p},x] && GtQ[p,0]

3:  ∫(((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  when  p>0 ∧ q≠-1

Reference: G&R 2.728.1, CRC 501, A&S 4.1.50'

Derivation: Integration by parts

Basis: (∂_x)(((a+b Log[c (x^n)]))^p)==((b n p (((a+b Log[c (x^n)]))^(p-1)))/x)

Rule: If  p>0 ∧ q≠-1, then

∫(((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  (((((d+e x))^(q+1)) (((a+b Log[c (x^n)]))^p))/(e (q+1)))-((b n p)/(e (q+1)))∫(((((d+e x))^(q+1))(((a+b Log[c (x^n)]))^(p-1)))/x)dx

Program code:

Int[(d_+e_.*x_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  (d+e*x)^(q+1)*(a+b*Log[c*x^n])^p/(e*(q+1)) - b*n*p/(e*(q+1))*Int[((d+e*x)^(q+1)*(a+b*Log[c*x^n])^(p-1))/x,x] /;
FreeQ[{a,b,c,d,e,n,p,q},x] && GtQ[p,0] && NeQ[q,-1] && (EqQ[p,1] || IntegersQ[2*p,2*q] && Not[IGtQ[q,0]] || EqQ[p,2] && NeQ[q,1])

2:  ∫(((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  when  p<-1 ∧ q>0

Rule: If  p<-1 ∧ q>0, then

∫(((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  
((x(((d+e x))^q) (((a+b Log[c (x^n)]))^(p+1)))/(b n (p+1)))+((d q)/(b n (p+1)))∫(((d+e x))^(q-1)) (((a+b Log[c (x^n)]))^(p+1))dx-((q+1)/(b n(p+1)))∫(((d+e x))^q) (((a+b Log[c (x^n)]))^(p+1))dx

Program code:

Int[(d_+e_.*x_)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_,x_Symbol] :=
  x*(d+e*x)^q*(a+b*Log[c*x^n])^(p+1)/(b*n*(p+1)) + 
  d*q/(b*n*(p+1))*Int[(d+e*x)^(q-1)*(a+b*Log[c*x^n])^(p+1),x] - 
  (q+1)/(b*n*(p+1))*Int[(d+e*x)^q*(a+b*Log[c*x^n])^(p+1),x] /;
FreeQ[{a,b,c,d,e,n},x] && LtQ[p,-1] && GtQ[q,0]

4.  ∫(((d+e (x^2)))^q) (a+b Log[c (x^n)])dx

1:  ∫(((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  when  q>0

Rule: If  q>0, then

∫(((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  ⟶  ((x (((d+e (x^2)))^q) (a+b Log[c (x^n)]))/(2 q+1))-((b n)/(2 q+1)) ∫(((d+e (x^2)))^q)dx+((2 d q)/(2 q+1)) ∫(((d+e (x^2)))^(q -1)) (a+b Log[c (x^n)])dx

Program code:

Int[(d_+e_.*x_^2)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  x*(d+e*x^2)^q*(a+b*Log[c*x^n])/(2*q+1) - 
  b*n/(2*q+1)*Int[(d+e*x^2)^q,x] + 
  2*d*q/(2*q+1)*Int[(d+e*x^2)^(q-1)*(a+b*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d,e,n},x] && GtQ[q,0]

2.  ∫(((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  when  q<-1

1:  ∫((a+b Log[c (x^n)])/(((d+e (x^2)))^(3/2)))dx

Rule:

∫((a+b Log[c (x^n)])/(((d+e (x^2)))^(3/2)))dx  ⟶  ((x (a+b Log[c (x^n)]))/(d (Sqrt[d+e (x^2)])))-((b n)/d) ∫(1/(Sqrt[d+e (x^2)]))dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])/(d_+e_.*x_^2)^(3/2),x_Symbol] :=
  x*(a+b*Log[c*x^n])/(d*Sqrt[d+e*x^2]) - b*n/d*Int[1/Sqrt[d+e*x^2],x] /;
FreeQ[{a,b,c,d,e,n},x]

2:  ∫(((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  when  q<-1

Rule: If  q<-1, then

∫(((d+e (x^2)))^q) (a+b Log[c (x^n)])dx  ⟶  -((x (((d+e (x^2)))^(q+1)) (a+b Log[c (x^n)]))/(2 d (q+1)))+((b n)/(2 d (q+1))) ∫(((d+e (x^2)))^(q+1))dx+((2 q+3)/(2 d (q+1))) ∫(((d+e (x^2)))^(q+1)) (a+b Log[c (x^n)])dx

Program code:

Int[(d_+e_.*x_^2)^q_*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  -x*(d+e*x^2)^(q+1)*(a+b*Log[c*x^n])/(2*d*(q+1)) + 
  b*n/(2*d*(q+1))*Int[(d+e*x^2)^(q+1),x] + 
  (2*q+3)/(2*d*(q+1))*Int[(d+e*x^2)^(q+1)*(a+b*Log[c*x^n]),x] /;
FreeQ[{a,b,c,d,e,n},x] && LtQ[q,-1]

3:  ∫((a+b Log[c (x^n)])/(d+e (x^2)))dx

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Rule: Let u->∫(1/(d+e (x^2)))dx, then

∫((a+b Log[c (x^n)])/(d+e (x^2)))dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])/(d_+e_.*x_^2),x_Symbol] :=
  With[{u=IntHide[1/(d+e*x^2),x]},  
  u*(a+b*Log[c*x^n]) - b*n*Int[u/x,x]] /;
FreeQ[{a,b,c,d,e,n},x]

4.  ∫((a+b Log[c (x^n)])/(Sqrt[d+e (x^2)]))dx

1.  ∫((a+b Log[c (x^n)])/(Sqrt[d+e (x^2)]))dx  when  d>0

1:  ∫((a+b Log[c (x^n)])/(Sqrt[d+e (x^2)]))dx  when  d>0 ∧ e>0

Derivation: Integration by parts

Basis: If  d>0, then (1/(Sqrt[d+e (x^2)]))==(∂_x)((ArcSinh[(((Sqrt[e]) x)/(Sqrt[d]))])/(Sqrt[e]))

Rule: If  d>0 ∧ e>0, then

∫((a+b Log[c (x^n)])/(Sqrt[d+e (x^2)]))dx  ⟶  ((ArcSinh[(((Sqrt[e]) x)/(Sqrt[d]))] (a+b Log[c (x^n)]))/(Sqrt[e]))-((b n)/(Sqrt[e])) ∫((ArcSinh[(((Sqrt[e]) x)/(Sqrt[d]))])/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  ArcSinh[Rt[e,2]*x/Sqrt[d]]*(a+b*Log[c*x^n])/Rt[e,2] - b*n/Rt[e,2]*Int[ArcSinh[Rt[e,2]*x/Sqrt[d]]/x,x] /;
FreeQ[{a,b,c,d,e,n},x] && GtQ[d,0] && PosQ[e]

2:  ∫((a+b Log[c (x^n)])/(Sqrt[d+e (x^2)]))dx  when  d>0 ∧ e≯0

Derivation: Integration by parts

Basis: If  d>0, then (1/(Sqrt[d+e (x^2)]))==(∂_x)((ArcSin[(((Sqrt[-e]) x)/(Sqrt[d]))])/(Sqrt[-e]))

Rule: If  d>0 ∧ e≯0, then

∫((a+b Log[c (x^n)])/(Sqrt[d+e (x^2)]))dx  ⟶  ((ArcSin[(((Sqrt[-e]) x)/(Sqrt[d]))] (a+b Log[c (x^n)]))/(Sqrt[-e]))-((b n)/(Sqrt[-e])) ∫((ArcSin[(((Sqrt[-e]) x)/(Sqrt[d]))])/x)dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  ArcSin[Rt[-e,2]*x/Sqrt[d]]*(a+b*Log[c*x^n])/Rt[-e,2] - b*n/Rt[-e,2]*Int[ArcSin[Rt[-e,2]*x/Sqrt[d]]/x,x] /;
FreeQ[{a,b,c,d,e,n},x] && GtQ[d,0] && NegQ[e]

2:  ∫((a+b Log[c (x^n)])/(Sqrt[d+e (x^2)]))dx  when  d≯0

Derivation: Piecewise constant extraction

Basis: (∂_x)((Sqrt[1+(e/d) (x^2)])/(Sqrt[d+e (x^2)]))==0

Rule: If  d≯0, then

∫((a+b Log[c (x^n)])/(Sqrt[d+e (x^2)]))dx  ⟶  ((Sqrt[1+(e/d) (x^2)])/(Sqrt[d+e (x^2)])) ∫((a+b Log[c (x^n)])/(Sqrt[1+(e/d) (x^2)]))dx

Program code:

Int[(a_.+b_.*Log[c_.*x_^n_.])/Sqrt[d_+e_.*x_^2],x_Symbol] :=
  Sqrt[1+e/d*x^2]/Sqrt[d+e*x^2]*Int[(a+b*Log[c*x^n])/Sqrt[1+e/d*x^2],x] /;
FreeQ[{a,b,c,d,e,n},x] && Not[GtQ[d,0]]

Int[(a_.+b_.*Log[c_.*x_^n_.])/(Sqrt[d1_+e1_.*x_]*Sqrt[d2_+e2_.*x_]),x_Symbol] :=
  Sqrt[1+e1*e2/(d1*d2)*x^2]/(Sqrt[d1+e1*x]*Sqrt[d2+e2*x])*Int[(a+b*Log[c*x^n])/Sqrt[1+e1*e2/(d1*d2)*x^2],x] /;
FreeQ[{a,b,c,d1,e1,d2,e2,n},x] && EqQ[d2*e1+d1*e2,0]

5:  ∫(((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  when  2 q∈ℤ ∧ r∈ℤ

Derivation: Integration by parts

Basis: (∂_x)(a+b Log[c (x^n)])==((b n)/x)

Note: If  q-(1/2)∈ℤ, then the terms of ∫(((d+e x))^q)dx will be algebraic functions or constants times an inverse function.

Rule: If  2 q∈ℤ ∧ r∈ℤ, let u->∫(((d+e (x^r)))^q)dx, then

∫(((d+e (x^r)))^q) (a+b Log[c (x^n)])dx  ⟶  u (a+b Log[c (x^n)])-b n ∫(u/x)dx

Program code:

Int[(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.]),x_Symbol] :=
  With[{u=IntHide[(d+e*x^r)^q,x]},  
  Dist[(a+b*Log[c*x^n]),u,x] - b*n*Int[SimplifyIntegrand[u/x,x],x] /;
 EqQ[r,1] && IntegerQ[q-1/2] || EqQ[r,2] && EqQ[q,-1] || InverseFunctionFreeQ[u,x]] /;
FreeQ[{a,b,c,d,e,n,q,r},x] && IntegerQ[2*q] && IntegerQ[r]

6:  ∫(((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  when  q∈ℤ ∧ (q>0 ∨ p∈(SuperPlus[ℤ])∧ r∈ℤ)

Derivation: Algebraic expansion

Rule: If  q∈ℤ ∧ (q>0 ∨ p∈(SuperPlus[ℤ])∧ r∈ℤ), then

∫(((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((a+b Log[c (x^n)]))^p) ExpandIntegrand[(((d+e (x^r)))^q),x]dx

Program code:

Int[(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  With[{u=ExpandIntegrand[(a+b*Log[c*x^n])^p,(d+e*x^r)^q,x]},
  Int[u,x] /;
 SumQ[u]] /;
FreeQ[{a,b,c,d,e,n,p,q,r},x] && IntegerQ[q] && (GtQ[q,0] || IGtQ[p,0] && IntegerQ[r])

U:  ∫(((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Rule:

∫(((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((d+e (x^r)))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[(d_+e_.*x_^r_.)^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Unintegrable[(d+e*x^r)^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,d,e,n,p,q,r},x]

N:  ∫(u^q) (((a+b Log[c (x^n)]))^p)dx  when  u==d+e (x^r)

Derivation: Algebraic normalization

Rule: If  u==d+e (x^r), then

∫(u^q) (((a+b Log[c (x^n)]))^p)dx  ⟶  ∫(((d+e x))^q) (((a+b Log[c (x^n)]))^p)dx

Program code:

Int[u_^q_.*(a_.+b_.*Log[c_.*x_^n_.])^p_.,x_Symbol] :=
  Int[ExpandToSum[u,x]^q*(a+b*Log[c*x^n])^p,x] /;
FreeQ[{a,b,c,n,p,q},x] && BinomialQ[u,x] && Not[BinomialMatchQ[u,x]]